$3 > 0 { print $1, $2 * $3} 

Note that the above command in a CLI will be invoked like this:

$ awk '$3 > 0 { print $1, $2 * $3}' emp.data

• But in this document we will just concentrate on it's language. The part inside the quotes is the complete awk program. It consists of a single pattern action statement.
• The pattern $3 > 0$ matches every input line in which the third column or field is greater than zero and executes the corresponding action.

{ print }

Or even this:

{ print $0 }

{ print $1, $3 }

• Expressions separated by a comma in a print statement are, by default, separated by a single blank when they are printed.

• Awk counts the number of fields in the current input line and stores the count in a built-in variable called NF.
• Any expression can be used after $ to denote a field number; the expression is evaluated and its numberic value is used as the field number.

{ print NF, $1, $NF }

• Awk provides another built-variable, called NR, that counts the number of lines read so far.

{ print NR, $0 }

{ print "total pay for", $1, "is", $2 * $3 }

total pay for Beth is 0
total pay for Dan is 0
total pay for Kathy is 40
total pay for Mark is 100
total pay for Mary is 121
total pay for Susie is 76.5

printf(format, value_1, value_2, ... , value_n)

• format: is a string that contains text to be printed verbatim, interspered with specifications of how each of the values is to be printed.
• A specification is a % followed by a few characters that control the format of a value.
• Thus, there must be as many % specifications in format as values to be printed.

{ printf("total pay for %s is $%.2f\n", $1, $2 * $3) }

total pay for Beth is $0.00
total pay for Dan is $0.00
total pay for Kathy is $40.00
total pay for Mark is $100.00
total pay for Mary is $121.00
total pay for Susie is $76.50

• %s: Specifices that the first value is a string of characters.
• %.2f: Specifices that the second value ($2*$3) is a number with 2 digits after decimal point.
• \n: Newline
• With printf, no blanks or newlines are produced automatically; you must create them yourself.

{ printf("%-8s $%6.2f\n",$1, $2 * $3)}

Beth     $  0.00
Dan      $  0.00
Kathy    $ 40.00
Mark     $100.00
Mary     $121.00
Susie    $ 76.50

• %-8s Prints a name as a string of characters left justified in a field 8 characters wide.
• %6.2f prints pay as a number with two digits after the decimal point, in a field 6 characters wide.

• Employees who earn more than or equal to $5 per hour:

$2 >= 5

• Employees whose total pay exceeds $50

$2 * $3 > 50 { printf("$%.2f for %s\n", $2 * $3, $1)}

$100.00 for Mark
$121.00 for Mary
$76.50 for Susie

$1 == "Susie"

Susie 4.25   18

• The text pattern can also be regular expressions

• Logical operators can be used: &&, || and !

$2 >= 4
$3 >= 20

!($2 < 4 && $3 < 20)

• Awk is an excellent tool for checking that data has reasonable values and is in the right format, a task that is often called data validation.
• Data validation is essentially negative: instead of printing lines with desirable properties, one prints lines that are suspicious.

NF != 3 { print $0, "number of files is not equal to 3"}

If there are no errors, there's no output.

$2 > 10 { print $0, "rate exceeds $10 per hour"}

• The special pattern BEGIN matches before the first line of the first input ·file is read, and END matches after the last line of the last file has been processed.

BEGIN { print "NAME  RATE   HOURS"; print ""}
      { print }

NAME  RATE   HOURS

Beth  4.00   0
Dan   3.75   0
Kathy 4.00   10
Mark  5.00   20
Mary  5.50   22
Susie 4.25   18

• Computing number of employees

END { print NR, "employees" }

6 employees

• Compute average pay

    { pay = pay + $2 * $3 }
END { print NR, "employees" 
      print "total pay is", pay
      print "average pay is", pay/NR
    }

6 employees
total pay is 337.5
average pay is 56.25

• Awk variables can hold strings of characters.
• Variables used to store strings begin life holding the null string.

$2 > maxrate { maxrate = $2; maxemp = $1 }
END { print "highest hourly rate:", maxrate, "for", maxemp }

highest hourly rate: 5.50 for Mary

• In the above awk code, the variable maxemp holds a string.

• Combine all the employee names into a single string:

    { names = names $1 " " }
END { print names }

Beth Dan Kathy Mark Mary Susie

    { last = $0 }
END { print last }

Susie 4.25   18

• Arithematic functions for square roots, logarithms, random numbers etc.
• length: Counts the number of characters in a string

{ print $1, length($1) }

Beth 4
Dan 3
Kathy 5
Mark 4
Mary 4
Susie 5

• In the below program, for convenience we will treat each field as word.

    { nc = nc + length($0) + 1 } # 1 for newline
    { nw = nw + NF }
END { print NR, "lines", nw, "words", nc, "characters" }

6 lines 18 words 94 characters

• Compute total and average pay of employees making more than $6 per hour.

$2 > 6 { n = n + 1; pay = pay + $2 * $3 }
END    { if (n > 0)
             print n, "employees total pay is", pay, "average pay is", pay/n
         else
             print "no employees are paid more than $6/hour"
       }

no employees are paid more than $6/hour